别怕|有调节的平行中介也没那么难-第一段（显变量）

小伙伴们大家好啊，我是愿意为你们服务的小婉，很久没有给大家推送MPLUS代码的文章了，最近在给大家指导的过程中，遇到小伙伴问有调节的平行中介和有调节的链式中介该怎么写，所以安排了“别怕”系列，陆陆续续会给大家更新有调节的中介的各种情况下的代码，别忘了关注噢。这期就先给大家讲讲有调节的平行中介-显变量篇怎么写。

显变量

本文举例部分采用显变量，一个自变量、二个中介变量，一个因变量。

模型 

代码--可复制版本

VARIABLE:

  NAMES ARE NU X M1 M2 Y W;

  USEVARIABLES = X M1 M2 W Y XW;

DEFINE:  XW = X*W;

ANALYSIS:

   TYPE = GENERAL;

   ESTIMATOR = ML;

   BOOTSTRAP = 1000;

MODEL:

   Y ON M1 (b1);

   Y ON M2 (b2);

   Y ON X (cdash);

   M1 ON X (a1);

   M1 ON W (a2);

   M1 ON XW(a3);

   M2 ON X (d1);

   M2 ON W (d2);

   M2 ON XW(d3);

MODEL CONSTRAINT:

    NEW(LOW_W MED_W HIGH_W

    IND_LOW1 IND_MED1 IND_HI1

    IMM1 

    IND_LOW2 IND_MED2 IND_HI2

    IMM2

    TOT_LOWW TOT_MEDW TOT_HIW);

   LOW_W =-1.079266; !W的1-sd,此处需要用自己的数据替换

   MED_W = 0;  

   HIGH_W =1.079266;  !W的1+sd,此处需要用自己的数据替换  

   ! M1的中介作用

    IND_LOW1 = a1*b1 + a3*b1*LOW_W;

    IND_MED1 = a1*b1 + a3*b1*MED_W;

    IND_HI1 = a1*b1 + a3*b1*HIGH_W; 

    IMM1 = a3*b1;! M1的有调节中介作用

   ! M2的中介作用

    IND_LOW2 = d1*b2 + d3*b2*LOW_W;

    IND_MED2 = d1*b2 + d3*b2*MED_W;

    IND_HI2 = d1*b2 + d3*b2*HIGH_W; 

    IMM2 = d3*b2;! M2的有调节中介作用

   !总效应

    TOT_LOWW = IND_LOW1 +IND_LOW2+ cdash;

    TOT_MEDW = IND_MED1 +IND_MED2+ cdash;

    TOT_HIW = IND_HI1 +IND_HI2+ cdash;

    OUTPUT: STAND CINT(bcbootstrap);

毕业路漫漫，我们愿做你的好伙伴

©无条件欢迎分享转发

注：本号的所有文章和视频均为版权所有，非常欢迎同学们分享转发,转载需授权。

                                                                          👇

“感觉有用，给个鼓励吧”