【FF14】 6.4战职640HQ作业 （豪华版）
640HQ专家版1:
/ac "坚信" <wait.3>
/ac "专心致志" <wait.3>
/ac "掌握" <wait.2>
/ac "崇敬" <wait.2>
/ac "俭约" <wait.2>
/ac "集中制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "模范制作" <wait.3>
/ac "俭约加工" <wait.3>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
640HQ专家版2：
/ac "掌握" <wait.2>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
/ac "改革" <wait.2>
/ac "观察" <wait.3>
/ac "注视加工" <wait.3>
/ac "观察" <wait.3>
/ac "注视加工" <wait.3>
/ac "改革" <wait.2>
/ac "工匠的神技" <wait.3>
/ac "阔步" <wait.2>
/ac "比尔格的祝福" <wait.3>
640HQ专家版3：（两个宏刚刚好写不下555）
/ac "制作" <wait.3>
640HQ高禁断1：
/ac "坚信" <wait.3>
/ac "掌握" <wait.2>
/ac "崇敬" <wait.2>
/ac "俭约" <wait.2>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "俭约加工" <wait.3>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
640HQ高禁断2：
/ac "掌握" <wait.2>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
/ac "阔步" <wait.2>
/ac "改革" <wait.2>
/ac "观察" <wait.3>
/ac "注视加工" <wait.3>
/ac "秘诀" <wait.3>
/ac "阔步" <wait.2>
/ac "比尔格的祝福" <wait.3>
/ac "制作" <wait.3>
（注意倒数第四行宏”秘诀“是为了防止”注视加工“之后出最高质量从而导致“比尔格的祝福”在低质量的情况下使用，即使”秘诀“不生效，CP也完全够用）
高禁断半成品HQ1：
/ac "坚信" <wait.3>
/ac "掌握" <wait.2>
/ac "崇敬" <wait.2>
/ac "长期俭约" <wait.2>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "精修" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "秘诀" <wait.3>
高禁断半成品HQ2：
/ac "阔步" <wait.2>
/ac "比尔格的祝福" <wait.3>
/ac "模范制作" <wait.3>
高禁断半成品NQ：
/ac "坚信" <wait.3>
/ac "崇敬" <wait.2>
/ac "长期俭约" <wait.2>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "模范制作" <wait.3>
以上就是我用的宏啦，如果觉得有帮助的话请三连支持一下哦~~
