战职640HQ宏作业(高配版)
1.专家满配版
640HQ专家版1:
/ac "坚信" <wait.3>
/ac "专心致志" <wait.3>
/ac "掌握" <wait.2>
/ac "崇敬" <wait.2>
/ac "俭约" <wait.2>
/ac "集中制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "模范制作" <wait.3>
/ac "俭约加工" <wait.3>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
640HQ专家版2:
/ac "掌握" <wait.2>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
/ac "改革" <wait.2>
/ac "观察" <wait.3>
/ac "注视加工" <wait.3>
/ac "观察" <wait.3>
/ac "注视加工" <wait.3>
/ac "改革" <wait.2>
/ac "工匠的神技" <wait.3>
/ac "阔步" <wait.2>
/ac "比尔格的祝福" <wait.3>
640HQ专家版3:(两个宏刚刚好写不下555)
/ac "制作" <wait.3>

2.高禁断版
640HQ高禁断1:
/ac "坚信" <wait.3>
/ac "掌握" <wait.2>
/ac "崇敬" <wait.2>
/ac "俭约" <wait.2>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "俭约加工" <wait.3>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
640HQ高禁断2:
/ac "掌握" <wait.2>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
/ac "阔步" <wait.2>
/ac "改革" <wait.2>
/ac "观察" <wait.3>
/ac "注视加工" <wait.3>
/ac "秘诀" <wait.3>
/ac "阔步" <wait.2>
/ac "比尔格的祝福" <wait.3>
/ac "制作" <wait.3>
(注意倒数第四行宏”秘诀“是为了防止”注视加工“之后出最高质量从而导致“比尔格的祝福”在低质量的情况下使用,即使”秘诀“不生效,CP也完全够用,下文的“秘诀”也同理)
高禁断半成品HQ1:
/ac "坚信" <wait.3>
/ac "掌握" <wait.2>
/ac "崇敬" <wait.2>
/ac "长期俭约" <wait.2>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "精修" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "秘诀" <wait.3>
高禁断半成品HQ2:
/ac "阔步" <wait.2>
/ac "比尔格的祝福" <wait.3>
/ac "模范制作" <wait.3>
高禁断半成品NQ:
/ac "坚信" <wait.3>
/ac "崇敬" <wait.2>
/ac "长期俭约" <wait.2>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "模范制作" <wait.3>
2.1.爆发药篇
由于up主目前未作出全NQ材料且保证优质率的作业,制作爆发药的时候有且只有一个素材能作为HQ垫子,因此初期品质为7020/14040。制作时需要近东虾香饭HQ,不需要爆发药。
垫1爆发药1:
/ac "坚信" <wait.3>
/ac "掌握" <wait.2>
/ac "崇敬" <wait.2>
/ac "俭约" <wait.2>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "阔步" <wait.2>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
/ac "掌握" <wait.2>
/ac "改革" <wait.2>
垫1爆发药2:
/ac "俭约加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "秘诀" <wait.3>
/ac "阔步" <wait.2>
/ac "比尔格的祝福" <wait.3>
/ac "制作" <wait.3>
2.2 食物篇
6.4的新食物和以前一样,有三个材料可以作为HQ垫子,制作时需要近东虾香饭HQ,不需要爆发药。
上文高禁断版本的练习宏期望最终质量为11845/14040,因此建议不同的垫子使用不同的宏。
2.2.1 大部分食物垫一个的初期品质最低为2500左右因此如果只想垫一个的话可以使用640HQ高禁断1和2
{P.S.:6.4新食物里有一个食物的制作材料之中,有一个材料做垫子时初期质量仅增加753,请不要用这个做垫子!!!(太低啦真不行)}
2.2.2 选择任意两个材料做垫子的初期品质为3886~4490,为了统一宏,以下使用的宏最终期望为10815/14040,适配所有使用两个HQ材料的食物。
垫2食物1:
/ac "坚信" <wait.3>
/ac "掌握" <wait.2>
/ac "崇敬" <wait.2>
/ac "俭约" <wait.2>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "坯料制作" <wait.3>
/ac "俭约加工" <wait.3>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
垫2食物2:
/ac "掌握" <wait.2>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "加工" <wait.3>
/ac "中级加工" <wait.3>
/ac "上级加工" <wait.3>
/ac "改革" <wait.2>
/ac "俭约加工" <wait.3>
/ac "秘诀" <wait.3>
/ac "阔步" <wait.2>
/ac "比尔格的祝福" <wait.3>
/ac "制作" <wait.3>
2.2.3 如果选择垫3个材料做食物,初期品质为7020/14040与爆发药一致,因此可以使用制作爆发药的宏:垫1爆发药1和垫1爆发药2