[MCBE] 服主们绝对不能错过的指令1 可互传高阶雪球菜单!

Minecraft 高阶雪球菜单命令解析与分享
·一个完整的多级雪球菜单包含一下几个部分:
①显示模块
②低头关闭模块
③扔雪球加分模块
④进位与归位模块
⑤返回上一页模块
⑥具体功能模块
— — — — —
⓪前期准备:更新游戏规则,创建计分版,设置常加载区域
(本部分命令在聊天框输入即可)
/gamerule commandblockoutput false
(关闭命令方块执行提示)
/gamerule sendcommandfeedback false
(关闭命令方块反馈提示)
/tickingarea add 坐标 坐标
(设置常加载区域)
/scoreboard objectives add 雪球菜单 dummy
(创建 “雪球菜单” 计分版)
/scoreboard objectives add tpa dummy
(创建 “tpa” 计分版)
/scoreboard objectives add T_time dummy
(创建 “T_time” 计分版)
①显示模块
⑴雪球菜单一级面板
【循环 无条件 保持开启】
/execute @a[scores={雪球菜单=0}] ~~~ titleraw @s actionbar {"rawtext":[{"text":"§l 雪球菜单§d
•=================•
§r§71.传送菜单
§r§72.原地升天
§r§73.游戏模式
§r§74.设重生点
§r§75.设传送点
§r§76.个人信息
§r§77.玩家互传
§r§78.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"}]}
【连锁 无条件 保持开启】
/execute @a[scores={雪球菜单=!..0}] ~~~ titleraw @s actionbar {"rawtext":[{"translate":"%%9","with":{"rawtext":[{"selector":"@s[scores={雪球菜单=..1}]"},{"selector":"@s[scores={雪球菜单=..2}]"},{"selector":"@s[scores={雪球菜单=..3}]"},{"selector":"@s[scores={雪球菜单=..4}]"},{"selector":"@s[scores={雪球菜单=..5}]"},{"selector":"@s[scores={雪球菜单=..6}]"}, {"selector":"@s[scores={雪球菜单=..7}]"}, {"selector":"@s[scores={雪球菜单=..8}]"},{"text":"§l §b循§f环大陆§d
•=================•
§l§b1.传送菜单
§r§72.原地升天
§r§73.游戏模式
§r§74.设重生点
§r§75.设传送点
§r§76.个人信息
§r§77.玩家互传
§r§78.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"},{"text":"§l 雪§b球§f菜单§d
•=================•
§r§71.传送菜单
§l§b2.原地升天
§r§73.游戏模式
§r§74.设重生点
§r§75.设传送点
§r§76.个人信息
§r§77.玩家互传
§r§78.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"},{"text":"§l 循环§b大§f陆§d
•=================•
§r§71.传送菜单
§r§72.原地升天
§l§b3.游戏模式
§r§74.设重生点
§r§75.设传送点
§r§76.个人信息
§r§77.玩家互传
§r§78.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"},{"text":"§l 雪球菜§b单§f§d
•=================•
§r§71.传送菜单
§r§72.原地升天
§r§73.游戏模式
§l§b4.设重生点
§r§75.设传送点
§r§76.个人信息
§r§77.玩家互传
§r§78.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"},{"text":"§l §b循§f环大陆§d
•=================•
§r§71.传送菜单
§r§72.原地升天
§r§73.游戏模式
§r§74.设重生点
§l§b5.设传送点
§r§76.个人信息
§r§77.玩家互传
§r§78.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"},{"text":"§l 雪§b球§f菜单§d
•=================•
§r§71.传送菜单
§r§72.原地升天
§r§73.游戏模式
§r§74.设重生点
§r§75.设传送点
§l§b6.个人信息
§r§77.玩家互传
§r§78.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"},{"text":"§l 循环§b大§f陆§d
•=================•
§r§71.传送菜单
§r§72.原地升天
§r§73.游戏模式
§r§74.设重生点
§r§75.设传送点
§r§76.个人信息
§l§b7.玩家互传
§r§78.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"},{"text":"§l 雪球菜§b单§f§d
•=================•
§r§71.传送菜单
§r§72.原地升天
§r§73.游戏模式
§r§74.设重生点
§r§75.设传送点
§r§76.个人信息
§r§77.玩家互传
§l§b8.快捷聊天
§d§l•=================•
§a抬头确认 §c低头取消
§r
§r
§r"}]}}]}
⑵雪球菜单二/三级面板
【连锁 无条件 保持开启】
/execute @a[scores={雪球菜单=!..9}] ~~~ titleraw @s actionbar {"rawtext":[{"translate":"%%8","with":{"rawtext":[{"selector":"@s[scores={雪球菜单=..10}]"},{"selector":"@s[scores={雪球菜单=..11}]"},{"selector":"@s[scores={雪球菜单=..12}]"},{"selector":"@s[scores={雪球菜单=..13}]"},{"selector":"@s[scores={雪球菜单=..14}]"},{"selector":"@s[scores={雪球菜单=..15}]"},{"selector":"@s[scores={雪球菜单=..16}]"},{"text":"§l 传送菜单§d
•=================•
§r§71.主城
§r§72.生存区
§r§73.传送门走廊
§r§74.商城
§r§75.个性工坊
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送菜单§d
•=================•
§l§b1.主城
§r§72.生存区
§r§73.传送门走廊
§r§74.商城
§r§75.个性工坊
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送菜单§d
•=================•
§r§71.主城
§l§b2.生存区
§r§73.传送门走廊
§r§74.商城
§r§75.个性工坊
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送菜单§d
•=================•
§r§71.主城
§r§72.生存区
§l§b3.传送门走廊
§r§74.商城
§r§75.个性工坊
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送菜单§d
•=================•
§r§71.主城
§r§72.生存区
§r§73.传送门走廊
§l§b4.商城
§r§75.个性工坊
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送菜单§d
•=================•
§r§71.主城
§r§72.生存区
§r§73.传送门走廊
§r§74.商城
§l§b5.个性工坊
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送菜单§d
•=================•
§r§71.主城
§r§72.生存区
§r§73.传送门走廊
§r§74.商城
§r§75.个性工坊
§d§l•=================•
§l§e返回上一页
§a抬头确认 §c低头取消
§r"}]}}]}
【连锁 无条件 保持开启】
/execute @a[scores={雪球菜单=!..29}] ~~~ titleraw @s actionbar {"rawtext":[{"translate":"%%6","with":{"rawtext":[{"selector":"@s[scores={雪球菜单=..30}]"},{"selector":"@s[scores={雪球菜单=..31}]"},{"selector":"@s[scores={雪球菜单=..32}]"},{"selector":"@s[scores={雪球菜单=..33}]"},{"selector":"@s[scores={雪球菜单=..34}]"},{"text":"§l 游戏模式§d
•=================•
§r§71.生存模式
§r§72.冒险模式
§r§73.创造模式
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 游戏模式§d
•=================•
§l§a1.生存模式
§r§72.冒险模式
§r§73.创造模式
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 游戏模式§d
•=================•
§r§71.生存模式
§l§c2.冒险模式
§r§73.创造模式
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 游戏模式§d
•=================•
§r§71.生存模式
§r§72.冒险模式
§l§d3.创造模式
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 游戏模式§d
•=================•
§r§71.生存模式
§r§72.冒险模式
§r§73.创造模式
§d§l•=================•
§l§e返回上一页
§a抬头确认 §c低头取消
§r"}]}}]}
【连锁 无条件 保持开启】
/execute @a[scores={雪球菜单=!..49}] ~~~ titleraw @s actionbar {"rawtext":[{"translate":"%%5","with":{"rawtext":[{"selector":"@s[scores={雪球菜单=..50}]"},{"selector":"@s[scores={雪球菜单=..51}]"},{"selector":"@s[scores={雪球菜单=..52}]"},{"selector":"@s[scores={雪球菜单=..53}]"},{"text":"§l 传送点功能§d
•=================•
§r§71.设置传送点
§r§72.前往传送点
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§l§b1.设置传送点
§r§72.前往传送点
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§r§71.设置传送点
§l§b2.前往传送点
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§r§71.设置传送点
§r§72.前往传送点
§d§l•=================•
§l§e返回上一页
§a抬头确认 §c低头取消
§r"}]}}]}
【连锁 无条件 保持开启】
/execute @a[scores={雪球菜单=!..499}] ~~~ titleraw @s actionbar {"rawtext":[{"translate":"%%6","with":{"rawtext":[{"selector":"@s[scores={雪球菜单=..500}]"},{"selector":"@s[scores={雪球菜单=..501}]"},{"selector":"@s[scores={雪球菜单=..502}]"},{"selector":"@s[scores={雪球菜单=..503}]"},{"selector":"@s[scores={雪球菜单=..504}]"},{"text":"§l 传送点功能§d
•=================•
§r§7·设置 传送点1
§r§7·设置 传送点2
§r§7·设置 传送点3
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§l§b·设置 传送点1
§r§7·设置 传送点2
§r§7·设置 传送点3
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§r§7·设置 传送点1
§l§b·设置 传送点2
§r§7·设置 传送点3
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§r§7·设置 传送点1
§r§7·设置 传送点2
§l§b·设置 传送点3
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§r§7·设置 传送点1
§r§7·设置 传送点2
§r§7·设置 传送点3
§d§l•=================•
§l§e返回上一页
§a抬头确认 §c低头取消
§r"}]}}]}
【连锁 无条件 保持开启】
/execute @a[scores={雪球菜单=!..509}] ~~~ titleraw @s actionbar {"rawtext":[{"translate":"%%6","with":{"rawtext":[{"selector":"@s[scores={雪球菜单=..510}]"},{"selector":"@s[scores={雪球菜单=..511}]"},{"selector":"@s[scores={雪球菜单=..512}]"},{"selector":"@s[scores={雪球菜单=..513}]"},{"selector":"@s[scores={雪球菜单=..514}]"},{"text":"§l 传送点功能§d
•=================•
§r§7·前往 传送点1
§r§7·前往 传送点2
§r§7·前往 传送点3
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§l§b·前往 传送点1
§r§7·前往 传送点2
§r§7·前往 传送点3
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§r§7·前往 传送点1
§l§b·前往 传送点2
§r§7·前往 传送点3
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§r§7·前往 传送点1
§r§7·前往 传送点2
§l§b·前往 传送点3
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 传送点功能§d
•=================•
§r§7·前往 传送点1
§r§7·前往 传送点2
§r§7·前往 传送点3
§d§l•=================•
§l§e返回上一页
§a抬头确认 §c低头取消
§r"}]}}]}
【连锁 无条件 保持开启】
/execute @a[scores={雪球菜单=!..69}] ~~~ titleraw @s actionbar {"rawtext":[{"translate":"%%5","with":{"rawtext":[{"selector":"@s[scores={雪球菜单=..70}]"},{"selector":"@s[scores={雪球菜单=..71}]"},{"selector":"@s[scores={雪球菜单=..72}]"},{"selector":"@s[scores={雪球菜单=..73}]"},{"text":"§l 玩家互传§d
•=================•
§r§71.发起传送
§r§72.接受传送
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 玩家互传§d
•=================•
§l§b1.发起传送
§r§72.接受传送
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 玩家互传§d
•=================•
§r§71.发起传送
§l§b2.接受传送
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 玩家互传§d
•=================•
§r§71.发起传送
§r§72.接受传送
§d§l•=================•
§l§e返回上一页
§a抬头确认 §c低头取消
§r"}]}}]}
【连锁 无条件 保持开启】
/execute @a[scores={雪球菜单=!..79}] ~~~ titleraw @s actionbar {"rawtext":[{"translate":"%%6","with":{"rawtext":[{"selector":"@s[scores={雪球菜单=..80}]"},{"selector":"@s[scores={雪球菜单=..81}]"},{"selector":"@s[scores={雪球菜单=..82}]"},{"selector":"@s[scores={雪球菜单=..83}]"},{"selector":"@s[scores={雪球菜单=..84}]"},{"text":"§l 发言功能§d
•=================•
§r§71.常规发言
§r§72.连续发言
§r§73.施展符箓
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 发言功能§d
•=================•
§l§b1.常规发言
§r§72.连续发言
§r§73.施展符箓
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 发言功能§d
•=================•
§r§71.常规发言
§l§b2.连续发言
§r§73.施展符箓
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 发言功能§d
•=================•
§r§71.常规发言
§r§72.连续发言
§l§b3.施展符箓
§d§l•=================•
§f返回上一页
§a抬头确认 §c低头取消
§r"},{"text":"§l 发言功能§d
•=================•
§r§71.常规发言
§r§72.连续发言
§r§73.施展符箓
§d§l•=================•
§l§e返回上一页
§a抬头确认 §c低头取消
§r"}]}}]}
②低头关闭模块
【循环 无条件 保持开启】
/title @a[rxm=88,scores={雪球菜单=0..}] actionbar §b 雪球菜单已关闭
§eThe menu is closed
【连锁 无条件 保持开启】
/playsound random.enderchestopen @a[rxm=88,scores={雪球菜单=0..}]
【连锁 无条件 保持开启】
/scoreboard players reset @a[rxm=88] 雪球菜单
③扔雪球加分模块
【循环 无条件 保持开启】
/execute @e[type=snowball] ~~~ scoreboard players add @p[r=2] 雪球菜单 1
【连锁 无条件 保持开启】
/execute @e[type=snowball] ~~~ give @p[m=!1,r=2] snowball
【连锁 无条件 保持开启】
/execute @e[type=snowball] ~~~ playsound random.orb @p[r=2]
【连锁 无条件 保持开启】
/kill @e[type=snowball]
④进位与归位模块
【循环 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=9}] 雪球菜单 1
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=17..29}] 雪球菜单 11
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=1}] 雪球菜单 10
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=35..49}] 雪球菜单 31
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=3}] 雪球菜单 30
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=54..69}] 雪球菜单 51
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=5}] 雪球菜单 50
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=505..509}] 雪球菜单 501
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=51}] 雪球菜单 500
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=515..}] 雪球菜单 511
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=52}] 雪球菜单 510
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=74..79}] 雪球菜单 71
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=7}] 雪球菜单 70
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=85..499}] 雪球菜单 81
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=8}] 雪球菜单 80
⑤返回上一页模块
【循环 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=16},rx=-88] 雪球菜单 0
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=34},rx=-88] 雪球菜单 0
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=53},rx=-88] 雪球菜单 0
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=504},rx=-88] 雪球菜单 50
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=514},rx=-88] 雪球菜单 50
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=73},rx=-88] 雪球菜单 0
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={雪球菜单=84},rx=-88] 雪球菜单 0
⑥具体功能模块
⑴传送菜单
【循环 无条件 保持开启】
/tp @a[rx=-88,scores={雪球菜单=11}] 主城坐标
【连锁 无条件 保持开启】
/tellraw @a[rx=-88,scores={雪球菜单=11}] {"rawtext":[{"text":"[§l传送只因§r] §a已传送至§b主城"}]}
【连锁 无条件 保持开启】
/tp @a[rx=-88,scores={雪球菜单=12}] 生存区坐标
【连锁 无条件 保持开启】
/tellraw @a[rx=-88,scores={雪球菜单=12}] {"rawtext":[{"text":"[§l传送只因§r] §a已传送至§a生存区"}]}
【连锁 无条件 保持开启】
/tp @a[rx=-88,scores={雪球菜单=13}] 传送门走廊坐标
【连锁 无条件 保持开启】
/tellraw @a[rx=-88,scores={雪球菜单=13}] {"rawtext":[{"text":"[§l传送只因§r] §a已传送至§d传送门走廊"}]}
【连锁 无条件 保持开启】
/tp @a[rx=-88,scores={雪球菜单=14}] 商城坐标
【连锁 无条件 保持开启】
/tellraw @a[rx=-88,scores={雪球菜单=14}] {"rawtext":[{"text":"[§l传送只因§r] §a已传送至§c商城"}]}
【连锁 无条件 保持开启】
/tp @a[rx=-88,scores={雪球菜单=15}] 个性工坊坐标
【连锁 无条件 保持开启】
/tellraw @a[rx=-88,scores={雪球菜单=15}] {"rawtext":[{"text":"[§l传送只因§r] §a已传送至§d个性工坊"}]}
【连锁 无条件 保持开启】
/playsound note.harp @a[rx=-88,scores={雪球菜单=11..15}]
【连锁 无条件 保持开启】
/scoreboard players reset @a[rx=-88,scores={雪球菜单=11..15}] 雪球菜单
⑵原地升天
【循环 无条件 保持开启】
/execute @a[rx=-88,scores={雪球菜单=2}] ~~~ gamerule showdeathmessages false
【连锁 无条件 保持开启】
/kill @a[rx=-88,scores={雪球菜单=2}]
【连锁 有条件的 保持开启】
/tellraw @a {"rawtext":[{"selector":"@a[rx=-88,scores={雪球菜单=2}]"},{"text":" 不知怎么地就一命呜呼了~"}]}
【连锁 无条件 保持开启】
/gamerule showdeathmessages true
【连锁 无条件 保持开启】
/scoreboard players reset @a[rx=-88,scores={雪球菜单=2}] 雪球菜单
⑶游戏模式
【循环 无条件 保持开启】
/gamemode 0 @a[rx=-88,scores={雪球菜单=31}]
【连锁 无条件 保持开启】
/gamemode 2 @a[rx=-88,scores={雪球菜单=32}]
【连锁 无条件 保持开启】
/gamemode 1 @a[rx=-88,scores={雪球菜单=33},tag=op]
【连锁 无条件 保持开启】
/title @a[rx=-88,scores={雪球菜单=33},tag=!op] actionbar §c您没有开启创造模式的权限
【连锁 无条件 保持开启】
/playsound note.harp @a[rx=-88,scores={雪球菜单=31..33}]
【连锁 无条件 保持开启】
/scoreboard players reset @a[rx=-88,scores={雪球菜单=31..33}] 雪球菜单
⑷设重生点
【循环 无条件 保持开启】
/execute @a[rx=-88,scores={雪球菜单=4}] ~~~ spawnpoint @s ~~~
【连锁 无条件 保持开启】
/tellraw @a[rx=-88,scores={雪球菜单=4}] {"rawtext":[{"text":"[§l科技只因§r] §e重生点已设置 "}]}
【连锁 无条件 保持开启】
/playsound note.harp @a[rx=-88,scores={雪球菜单=4}]
【连锁 无条件 保持开启】
/scoreboard players reset @a[rx=-88,scores={雪球菜单=4}] 雪球菜单
⑸设传送点(略)
⑹个人信息
【循环 无条件 保持开启】
/tag @a[rx=-88,scores={雪球菜单=6}] add 个人信息
【连锁 无条件 保持开启】
/playsound note.harp @a[rx=-88,scores={雪球菜单=6}]
【连锁 无条件 保持开启】
/scoreboard players reset @a[rx=-88,scores={雪球菜单=6}] 雪球菜单
【连锁 无条件 保持开启】
/execute @a[tag=个人信息] ~~~ titleraw @s actionbar {"rawtext":[{"text":" §l§b循环大陆 §e信息§a显示§r \n§d§l •========================================•§r\n §r§f[§l§e北京时间§r§f] "},{"score":{"name":"year","objective":"计时"}},{"text":"年"},{"score":{"name":"month","objective":"计时"}}, {"text":"月"},{"score":{"name":"day","objective":"计时"}}, {"text":"日 "},{"score":{"name":"hour","objective":"计时"}}, {"text":":"},{"score":{"name":"minute","objective":"计时"}}, {"text":":"},{"score":{"name":"second","objective":"计时"}},{"text":"\n §r§f[§l§a服务器延迟§r§f] "},{"score":{"name":"延迟显示","objective":"计时"}},{"text":" ms\n §r§f[§l§g玩家ID§r§f] §e"},{"selector":"@s"},{"text":"\n §r§f[§l§b在§e线§c时§a间§r§f] §e"},{"score":{"name":"@s","objective":"在线时间"}},{"text":" min\n §r§f[§l§b天璇币§r§f] §e"},{"score":{"name":"@s","objective":"天璇币"}},{"text":"\n §r§f[§l§d在线op§r§f] §g"},{"selector":"@a[tag=op]"},{"text":"\n §r§f[§l§6附近100格玩家§r§f] §6"},{"selector":"@a[r=100,rm=0.01,c=6]"},{"text":"\n §r§f[§l§c附近100格掉落物§r§f] §6"},{"selector":"@e[type=item,r=100,c=6]"},{"text":"§r\n§d§l •========================================•§r\n §l§c低头关闭信息显示\n\n\n"}]}
【连锁 无条件 保持开启】
/title @a[rxm=88,tag=个人信息] actionbar §d 信息显示已关闭
§cThe screen is closed
【连锁 无条件 保持开启】
/playsound random.enderchestopen @a[rxm=88,tag=个人信息]
【连锁 无条件 保持开启】
/tag @a[rxm=88,tag=个人信息] remove 个人信息
⑺玩家互传
❶发起传送
【循环 无条件 保持开启】
/scoreboard players add @a tpa 0
【连锁 无条件 保持开启】
/title @a[scores={tpa=1..}] times 0 70 0
【连锁 无条件 保持开启】
/title @a[scores={tpa=..0}] times 10 70 20
【连锁 无条件 保持开启】
/execute @a[rx=-88,scores={雪球菜单=71,tpa=..0}] ~~~ title @a[scores={tpa=1..}] title §c传送终止
【连锁 无条件 保持开启】
/execute @a[rx=-88,scores={雪球菜单=71,tpa=..0}] ~~~ title @a[scores={tpa=1..}] subtitle §e被 §b@s §e插队了( ̄• ̄)ゞ §a下次让对方快点接受哦
【连锁 无条件 保持开启】
/execute @a[rx=-88,scores={雪球菜单=71,tpa=..0}] ~~~ scoreboard players set @a[scores={tpa=1..}] tpa 0
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=71,tpa=..0}] tpa 60
【连锁 有条件的 保持开启】
/say §e玩家 §b@a[scores={tpa=60}] §e发出了传送请求 §a可通过雪球菜单接受传送请求 §c(1min有效期)
【连锁 有条件的 保持开启】
/execute @a ~~~ playsound random.levelup @s ~~~ 20 0.5
【连锁 无条件 保持开启】
/titleraw @a[scores={tpa=1..}] title {"rawtext":[{"text":"§b等待§e其他玩家§a接受传送"}]}
【连锁 无条件 保持开启】
/execute @a[scores={tpa=1..}] ~~~ titleraw @s subtitle {"rawtext":[{"text":" §e传送生效§b倒§a计§d时§f - "},{"score":{"name":"@s","objective":"tpa"}},{"text":"s \n\n§c低头取消传送"}]}
【连锁 无条件 保持开启】
/scoreboard players reset @a[rx=-88,scores={雪球菜单=71}] 雪球菜单
【连锁 无条件 保持开启】
/title @a[scores={tpa=1..},rxm=88] title §c传送取消
【连锁 无条件 保持开启】
/playsound random.enderchestopen @a[scores={tpa=1..},rxm=88]
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={tpa=1..},rxm=88] tpa 0
❷接受传送
【循环 无条件 保持开启】
/tag @a[rx=-88,scores={雪球菜单=72}] add tpd
【连锁 无条件 保持开启】
/scoreboard players reset @a[rx=-88,scores={雪球菜单=72}] 雪球菜单
【连锁 无条件 保持开启】
/tp @a[scores={tpa=1..}] @a[tag=tpd]
【连锁 有条件的 保持开启】
/say §e已将 §b@a[scores={tpa=1..}] §a传送至 §b@a[tag=tpd]
【连锁 有条件的 保持开启】
/playsound note.harp @a[scores={tpa=1..}]
【连锁 有条件的 保持开启】
/playsound note.harp @a[tag=tpd]
【连锁 有条件的 保持开启】
/title @a[scores={tpa=1..}] title §f
【连锁 有条件的 保持开启】
/title @a[scores={tpa=1..}] subtitle §a-•§b传送§e成功§c•-
【连锁 有条件的 保持开启】
/scoreboard players set @a[scores={tpa=1..}] tpa 0
【连锁 无条件 保持开启】
/tag * remove tpd
❸传送倒计时
【循环 无条件 保持开启 延迟20】
/scoreboard players remove @a[scores={tpa=1..}] tpa 1
⑻快捷聊天
❶常规发言
【循环 无条件 保持开启】
/give @a[rx=-88,scores={雪球菜单=81}] writable_book
【连锁 无条件 保持开启】
/playsound note.harp @a[rx=-88,scores={雪球菜单=81}]
【连锁 无条件 保持开启】
/scoreboard players set @a[rx=-88,scores={雪球菜单=81}] T_time 60
【连锁 无条件 保持开启】
/scoreboard players reset @a[rx=-88,scores={雪球菜单=81}] 雪球菜单
【连锁 无条件 保持开启】
/execute @a[scores={T_time=1..}] ~~~ titleraw @s actionbar {"rawtext":[{"text":" §l常规发言§e生效§b倒§a计§d时§f - "},{"score":{"name":"@s","objective":"T_time"}},{"text":"s §r
§d§l•========================================•
§r§b你已被给予§e书与笔§b 请将§e书名§b命名为你想说的话§a并扔出
§e即可§a不通过聊天栏§6直接发言 §c(有效期 1min)
§d§l•========================================•
§c低头取消发言"}]}
【连锁 无条件 保持开启】
/tag @r[scores={T_time=1..}] add T_bl
【连锁 无条件 保持开启】
/execute @a[tag=T_bl] ~~~ testfor @e[type=item,c=1,r=2]
【连锁 有条件的 保持开启】
/execute @a[tag=T_bl] ~~~ tellraw @a {"rawtext":[{"text":"<"},{"selector":"@s"},{"text":"> "},{"selector":"@e[type=item,c=1,r=2]"}]}
【连锁 有条件的 保持开启】
/scoreboard players set @a[tag=T_bl] T_time 0
【连锁 有条件的 保持开启】
/execute @a[tag=T_bl] ~~~ kill @e[type=item,c=1,r=2]
【连锁 无条件 保持开启】
/tag * remove T_bl
【连锁 无条件 保持开启】
/execute @a[scores={T_time=1..},rxm=88] ~~~ titleraw @s actionbar {"rawtext":[{"text":" §c§l发言取消 §r
§d§l•========================================•
§r§b你已被给予§e书与笔§b 请将§e书名§b命名为你想说的话§a并扔出
§e即可§a不通过聊天栏§6直接发言 §c(有效期 1min)
§d§l•========================================•
§c低头取消发言"}]}
【连锁 无条件 保持开启】
/playsound random.enderchestopen @a[scores={T_time=1..},rxm=88]
【连锁 无条件 保持开启】
/scoreboard players set @a[scores={T_time=1..},rxm=88] T_time 0
❷发言倒计时
【循环 无条件 保持开启 延迟20】
/scoreboard players remove @a[scores={T_time=1..}] T_time 1