align键控菜单2.0更新，优化演示

#初始化

scoreboard players add @a[rxm=88,scores={菜单=..-71}] "菜单" 1

execute as @a[scores={菜单=-99..-71}] unless entity @s[rxm=88] run scoreboard players add @s "菜单" -1

execute as @a[scores={菜单=..-71}] at @s unless block ~~~ air align y run scoreboard players set @s[rm=0.01] "菜单" -100

execute as @a[rxm=88,scores={菜单=..-71}] at @s unless block ~~~ air align y run title @s[rm=0.01] actionbar 请站在完整方块上打开此菜单

title @a[scores={菜单=-70..-10}] times 0 5 3

execute as @a[scores={菜单=-70..-10}] at @s align xyz run tp ~0.5~~0.5 ~ 0

execute as @a[scores={菜单=-70..-10}] at @s rotated ~ 0 run camera @s set example:example_free ease 1 linear pos ^0.8^1^2.2 rot 0 ~180

execute as @a[scores={菜单=-70..-10}] at @s run playsound beacon.activate @s ~~1~ 2 4

scoreboard players set @a[scores={菜单=-70..-10}] "菜单" 5

execute as @a[scores={菜单=-97..-71}] run titleraw @s actionbar {"rawtext":[{"translate":"%%9","with":{"rawtext":[{"selector":"@s[scores={菜单=-97..-94}]"},{"selector":"@s[scores={菜单=-97..-91}]"},{"selector":"@s[scores={菜单=-97..-88}]"},{"selector":"@s[scores={菜单=-97..-85}]"},{"selector":"@s[scores={菜单=-97..-82}]"},{"selector":"@s[scores={菜单=-97..-79}]"},{"selector":"@s[scores={菜单=-97..-76}]"},{"selector":"@s[scores={菜单=-97..-73}]"},{"text":"§o§4▎§c▌"},{"text":"§o§4▎§c▌§a正"},{"text":"§o§4▎§c▌§a正在"},{"text":"§o§4▎§c▌§a正在连"},{"text":"§o§4▎§c▌§a正在连接"},{"text":"§o§4▎§c▌§a正在连接中"},{"text":"§o§4▎§c▌§a正在连接中."},{"text":"§o§4▎§c▌§a正在连接中.."},{"text":"§o§4▎§c▌§a正在连接中..."}]}}]}

execute as @a[scores={菜单=-94..-73,菜单=!-96..-95,菜单=!-93..-92,菜单=!-90..-89,菜单=!-87..-86,菜单=!-84..-83,菜单=!-81..-80,菜单=!-78..-77,菜单=!-75..-74}] at @s run playsound random.click @s ~~1~ 2 5.1 2

#功能

execute as @a[scores={计时=..0}] at @s align xyz positioned ~0.5~~0.5 rotated ~ 0 positioned ^^^1 run scoreboard players add @s[r=0.99] "菜单" -3

execute as @a[scores={计时=..0}] at @s align xyz positioned ~0.5~~0.5 rotated ~ 0 positioned ^^^-1 run scoreboard players add @s[r=0.99] "菜单" 3

execute as @a[scores={计时=..0}] at @s align xyz positioned ~0.5~~0.5 rotated ~ 0 positioned ^1^^ run scoreboard players add @s[r=0.99] "菜单" -1

execute as @a[scores={计时=..0}] at @s align xyz positioned ~0.5~~0.5 rotated ~ 0 positioned ^-1^^ run scoreboard players add @s[r=0.99] "菜单" 1

scoreboard players add @a[scores={菜单=10..}] "菜单" -9

scoreboard players add @a[scores={菜单=-9..0}] "菜单" 9

execute as @a[scores={计时=..0}] at @s align xyz positioned ~0.5~~0.5 run playsound random.toast @s[rm=0.01] ~~1~ 0.4 5.1

execute as @a[scores={计时=..0}] at @s align xyz positioned ~0.5~~0.5 run scoreboard players set @s[rm=0.01] "计时" 5

scoreboard players add @a[scores={计时=1..,菜单=1..}] "计时" -1

#第一排

execute as @a[scores={菜单=1}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run tp 0 -59.5 0

execute as @a[scores={菜单=1}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run say 回城成功

execute as @a[scores={菜单=2}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run say 购买鸡蛋x1

execute as @a[scores={菜单=3}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run summon zombie ~~5~

#第二排

execute as @a[scores={菜单=4}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run say 签到成功

execute as @a[scores={菜单=5}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run say 等级不够

execute as @a[scores={菜单=6}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run say 桀桀桀

#第三排

execute as @a[scores={菜单=7}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run say 金币数：233

execute as @a[scores={菜单=8}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run say 设置，启动！

execute as @a[scores={菜单=9}] at @s align xyz positioned ~0.5~3~0.5 if entity @s[r=2.99] run say 已退出

#结束

execute as @a[scores={菜单=1..}] at @s align xyz positioned ~0.5~3~0.5 run camera @s[r=2.99] clear

execute as @a[scores={菜单=1..}] at @s align xyz positioned ~0.5~3~0.5 run playsound random.orb @s[r=2.99] ~~-2~ 0.8 1

execute as @a[scores={菜单=1..}] at @s align xyz positioned ~0.5~3~0.5 run scoreboard players set @s[r=2.99] "菜单" -100

execute as @a[scores={菜单=1..}] at @s align xyz positioned ~0.5~~0.5 run tp @s[rm=0.01] ~~~

#菜单显示

titleraw @a[scores={菜单=1}] title {"rawtext":[{"text":"§f     §a主城§f 商店 试炼\n\n     签到 公会 喊话\n\n     个人 设置 退出"}]}

titleraw @a[scores={菜单=2}] title {"rawtext":[{"text":"§f     主城 §a商店§f 试炼\n\n     签到 公会 喊话\n\n     个人 设置 退出"}]}

titleraw @a[scores={菜单=3}] title {"rawtext":[{"text":"§f     主城 商店 §a试炼§f\n\n     签到 公会 喊话\n\n     个人 设置 退出"}]}

titleraw @a[scores={菜单=4}] title {"rawtext":[{"text":"§f     主城 商店 试炼\n\n     §a签到§f 公会 喊话\n\n     个人 设置 退出"}]}

titleraw @a[scores={菜单=5}] title {"rawtext":[{"text":"§f     主城 商店 试炼\n\n     签到 §a公会§f 喊话\n\n     个人 设置 退出"}]}

titleraw @a[scores={菜单=6}] title {"rawtext":[{"text":"§f     主城 商店 试炼\n\n     签到 公会 §a喊话§f\n\n     个人 设置 退出"}]}

titleraw @a[scores={菜单=7}] title {"rawtext":[{"text":"§f     主城 商店 试炼\n\n     签到 公会 喊话\n\n     §a个人§f 设置 退出"}]}

titleraw @a[scores={菜单=8}] title {"rawtext":[{"text":"§f     主城 商店 试炼\n\n     签到 公会 喊话\n\n     个人 §a设置§f 退出"}]}

titleraw @a[scores={菜单=9}] title {"rawtext":[{"text":"§f     主城 商店 试炼\n\n     签到 公会 喊话\n\n     个人 设置 §a退出§f"}]}

#by 萌鲨无敌